% BibTeX standard bibliography style `plain'
	% version 0.99a for BibTeX versions 0.99a or later, LaTeX version 2.09.
	% Copyright (C) 1985, all rights reserved.
	% Copying of this file is authorized only if either
	% (1) you make absolutely no changes to your copy, including name, or
	% (2) if you do make changes, you name it something other than
	% btxbst.doc, plain.bst, unsrt.bst, alpha.bst, and abbrv.bst.
	% This restriction helps ensure that all standard styles are identical.
	% The file btxbst.doc has the documentation for this style.

ENTRY
  { address
    author
    bookauthor
    booktitle
    chapter
    edition
    editor
    howpublished
    institution
    journal
    key
    month
    note
    number
    organization
    pages
    publisher
    school
    series
    title
    type
    volume
    year
    isbn
    url
    accessdate
    language
  }
  {}
  { label }

INTEGERS { output.state before.all mid.sentence after.sentence after.block }

FUNCTION {init.state.consts}
{ #0 'before.all :=
  #1 'mid.sentence :=
  #2 'after.sentence :=
  #3 'after.block :=
}

STRINGS { s t }

FUNCTION {output.nonnull}
{ 's :=
  output.state mid.sentence =
    { ", " * write$ }
    { output.state after.block =
	{ add.period$ write$
	  newline$
	  "\newblock " write$
	}
	{ output.state before.all =
	    'write$
	    { add.period$ " " * write$ }
	  if$
	}
      if$
      mid.sentence 'output.state :=
    }
  if$
  s
}

FUNCTION {output.nocomma.nonnull}
{ 's :=
  output.state mid.sentence =
    { " " * write$ }
    { output.state after.block =
	    { add.period$ write$
	      newline$
	      "\newblock " write$
	    }
	    { output.state before.all =
	        'write$
	        { add.period$ " " * write$ }
	      if$
	    }
      if$
      mid.sentence 'output.state :=
    }
  if$
  s
}

FUNCTION {output.nocomma}
{ duplicate$ empty$
    'pop$
    'output.nocomma.nonnull
  if$
}

FUNCTION {output}
{ duplicate$ empty$
    'pop$
    'output.nonnull
  if$
}

FUNCTION {output.check}
{ 't :=
  duplicate$ empty$
    { pop$ "empty " t * " in " * cite$ * warning$ }
    'output.nonnull
  if$
}

FUNCTION {output.bibitem}
{ newline$
  "\bibitem{" write$
  cite$ write$
  "}" write$
  newline$
  ""
  before.all 'output.state :=
}

FUNCTION {fin.entry}
{ add.period$
  write$
  newline$
}

FUNCTION {new.block}
{ output.state before.all =
    'skip$
    { after.block 'output.state := }
  if$
}

FUNCTION {new.sentence}
{ output.state after.block =
    'skip$
    { output.state before.all =
	'skip$
	{ after.sentence 'output.state := }
      if$
    }
  if$
}

FUNCTION {not}
{   { #0 }
    { #1 }
  if$
}

FUNCTION {and}
{   'skip$
    { pop$ #0 }
  if$
}

FUNCTION {or}
{   { pop$ #1 }
    'skip$
  if$
}

FUNCTION {new.block.checka}
{ empty$
    'skip$
    'new.block
  if$
}

FUNCTION {new.block.checkb}
{ empty$
  swap$ empty$
  and
    'skip$
    'new.block
  if$
}

FUNCTION {new.sentence.checka}
{ empty$
    'skip$
    'new.sentence
  if$
}

FUNCTION {new.sentence.checkb}
{ empty$
  swap$ empty$
  and
    'skip$
    'new.sentence
  if$
}

FUNCTION {field.or.null}
{ duplicate$ empty$
    { pop$ "" }
    'skip$
  if$
}

FUNCTION {emphasize}
{ duplicate$ empty$
    { pop$ "" }
    { "{\em " swap$ * "}" * }
  if$
}

INTEGERS { nameptr namesleft numnames }

FUNCTION {format.names}
{ 's :=
  s num.names$ 'numnames :=
  #1 'nameptr :=
  s nameptr "{vv~}{ll}{, jj}" format.name$ "u" change.case$
  s nameptr "{ff}" format.name$ duplicate$ empty$
	'pop$
    { ", " swap$ * * }
  if$
  numnames #1 - 'namesleft :=
  { namesleft #0 > }
    { nameptr #1 + 'nameptr :=
      s nameptr "{ff}" format.name$ duplicate$ empty$
		'skip$
		{ " " * }
	  if$
	  s nameptr "{vv~}{ll}{, jj}" format.name$ "u" change.case$ *
      't :=
	  namesleft #1 >
	    { ", " * t * }
	    { t "OTHERS" =
		  	{ " \emph{and~al.}" * }
			{ " and " * t * }
	      if$
	    }
	  if$
      namesleft #1 - 'namesleft :=
    }
  while$
}

FUNCTION {format.names.old}
{ 's :=
  #1 'nameptr :=
  s num.names$ 'numnames :=
  numnames 'namesleft :=
    { namesleft #0 > }
    { s nameptr "{vv~}{ll}{, jj}" format.name$ "u" change.case$
      " " 
      s nameptr "{ff}" format.name$
      * * 't :=
      nameptr #1 >
	{ namesleft #1 >
	    { ", " * t * }
	    { t "OTHERS " =
		  	{ " et~al." * }
			{ ", " * t * }
	      if$
	    }
	  if$
	}
	't
      if$
      nameptr #1 + 'nameptr :=
      namesleft #1 - 'namesleft :=
    }
  while$
}

FUNCTION {format.authors}
{ author empty$
    { "" }
    { author format.names }
  if$
}

FUNCTION {format.editors}
{ editor empty$
    { "" }
    { editor format.names
      editor num.names$ #1 >
	{ ", eds" * }
	{ ", ed." * }
      if$
    }
  if$
}

FUNCTION {format.title}
{ title empty$
    { "" }
    { language empty$
		{ title "t" change.case$ }
		{ "\foreignlanguage{" language * "}{" *
		  title "t" change.case$ *
		  "}" *
		}
	  if$
	}
  if$
}


FUNCTION {n.dashify}
{ 't :=
  ""
    { t empty$ not }
    { t #1 #1 substring$ "-" =
	{ t #1 #2 substring$ "--" = not
	    { "--" *
	      t #2 global.max$ substring$ 't :=
	    }
	    {   { t #1 #1 substring$ "-" = }
		{ "-" *
		  t #2 global.max$ substring$ 't :=
		}
	      while$
	    }
	  if$
	}
	{ t #1 #1 substring$ *
	  t #2 global.max$ substring$ 't :=
	}
      if$
    }
  while$
}

FUNCTION {format.date}
{ year empty$
    { month empty$
	    { "" }
	    { "there's a month but no year in " cite$ * warning$
	      ""
	    }
      if$
    }
    { month empty$
	    { year }
	    { month " " * year * }
      if$
    }
  if$
}

FUNCTION {format.btitle}
{ title empty$
    { "" }
    { language empty$
		{ title }
		{ "\foreignlanguage{" language * "}{" *
		  title *
		  "}" *
		}
	  if$
      emphasize
      volume empty$
        { "" }
        { ". Vol. " volume * }
      if$
      *    
    }
  if$
}



FUNCTION {tie.or.space.connect}
{ duplicate$ text.length$ #3 <
    { "~" }
    { " " }
  if$
  swap$ * *
}

FUNCTION {either.or.check}
{ empty$
    'pop$
    { "can't use both " swap$ * " fields in " * cite$ * warning$ }
  if$
}

FUNCTION {format.bvolume}
{ volume empty$
    { "" }
    { "volume" volume tie.or.space.connect
      series empty$
	'skip$
	{ " of " * series emphasize * }
      if$
      "volume and number" number either.or.check
    }
  if$
}

FUNCTION {format.book.volume}
{ volume empty$
    { "" }
    { "volume" volume tie.or.space.connect }
  if$
}

FUNCTION {format.number.series}
{ series empty$
    { "" }
    { "(" series *
      number empty$
        { "" * }
        { "; " number * * }
      if$
       ")" *
    }
  if$  
}

FUNCTION {is.num}
{ chr.to.int$
  duplicate$ "0" chr.to.int$ < not
  swap$ "9" chr.to.int$ > not and
}

FUNCTION {extract.num}
{ duplicate$ 't :=
  "" 's :=
  { t empty$ not }
  { t #1 #1 substring$
    t #2 global.max$ substring$ 't :=
    duplicate$ is.num
      { s swap$ * 's := }
      { pop$ "" 't := }
    if$
  }
  while$
  s empty$
    'skip$
    { pop$ s }
  if$
}

FUNCTION {eng.ord}
{ duplicate$ "1" swap$ *
  #-2 #1 substring$ "1" =
     { "th" * }
     { duplicate$ #-1 #1 substring$
       duplicate$ "1" =
         { pop$ "st" * }
         { duplicate$ "2" =
             { pop$ "nd" * }
             { "3" =
                 { "rd" * }
                 { "th" * }
               if$
             }
           if$
          }
       if$
     }
   if$
}

FUNCTION {convert.edition}
{ extract.num "l" change.case$ 's :=
  s "first" = s "1" = or
    { "1st" 't := }
    { s "second" = s "2" = or
        { "2nd" 't := }
        { s "third" = s "3" = or
            { "3rd" 't := }
            { s "fourth" = s "4" = or
                { "4th" 't := }
                { s "fifth" = s "5" = or
                    { "5th" 't := }
                    { s #1 #1 substring$ is.num
                        { s eng.ord 't := }
                        { edition 't := }
                      if$
                    }
                  if$
                }
              if$
            }
          if$
        }
      if$
    }
  if$
  t
}

FUNCTION {format.edition}
{ edition empty$
    { "" }
    { edition convert.edition
	  output.state mid.sentence =
	    { "l" change.case$ " ed." * }
	    { "t" change.case$ " ed." * }
      if$
    }
  if$
}

INTEGERS { multiresult }

FUNCTION {multi.page.check}
{ 't :=
  #0 'multiresult :=
    { multiresult not
      t empty$ not
      and
    }
    { t #1 #1 substring$
      duplicate$ "-" =
      swap$ duplicate$ "," =
      swap$ "+" =
      or or
	{ #1 'multiresult := }
	{ t #2 global.max$ substring$ 't := }
      if$
    }
  while$
  multiresult
}

FUNCTION {format.abbrev.pages}
{ pages empty$
    { "" }
    { pages #1 #1 substring$ is.num 
        { pages multi.page.check
		    { "p." pages n.dashify tie.or.space.connect }
		    { "p." pages tie.or.space.connect }
          if$
        }
		{ pages }
      if$
    }
  if$
}

FUNCTION {format.pages}
{ pages empty$
    { "" }
    { pages #1 #1 substring$ is.num 
        { pages multi.page.check
		    { "Pages" pages n.dashify tie.or.space.connect }
		    { "Page" pages tie.or.space.connect }
          if$
        }
		{ pages }
      if$
    }
  if$
}


FUNCTION {format.vol.num.pages}
{ volume field.or.null
  number empty$
    'skip$
    { "(" number * ")" * *
      volume empty$
		{ "there's a number but no volume in " cite$ * warning$ }
		'skip$
      if$
    }
  if$
  pages empty$
    'skip$
    { duplicate$ empty$
		{ pop$ format.abbrev.pages }
		{ ", " * format.abbrev.pages * }
      if$
    }
  if$
}

FUNCTION {format.chapter.pages}
{ chapter empty$
    'format.pages
    { type empty$
	    { "Chapitre" }
	    { type }
      if$
      chapter tie.or.space.connect
      pages empty$
	    'skip$
	    { ", " * format.abbrev.pages * }
      if$
    }
  if$
}


FUNCTION {format.chapter}
{ chapter empty$
    { "" }
    { type empty$
	    { "Chapter" }
	    { type }
      if$
      chapter tie.or.space.connect
    }
  if$
}


FUNCTION {format.booktitle.volume}
{ booktitle empty$
    { "" }
    { booktitle
      volume empty$
        { "" }
        { ", vol." volume * }
      if$
      *
      emphasize
    }
  if$
}

FUNCTION {format.in.ed.booktitle}
{ booktitle empty$
    { "" }
    { editor empty$
	    { "\emph{In :} " format.booktitle.volume * }
	    { "\emph{In :} " format.editors * ", " * format.booktitle.volume * }
      if$
    }
  if$
}


FUNCTION {empty.misc.check}
{ author empty$ title empty$ howpublished empty$
  month empty$ year empty$ note empty$
  and and and and and
  key empty$ not and
    { "all relevant fields are empty in " cite$ * warning$ }
    'skip$
  if$
}

FUNCTION {format.thesis.type}
{ type empty$
    'skip$
    { pop$
      type "t" change.case$
    }
  if$
}

FUNCTION {format.tr.number}
{ type empty$
    { "Technical Report" }
    'type
  if$
  number empty$
    { "t" change.case$ }
    { number tie.or.space.connect }
  if$
}

FUNCTION {format.article.crossref}
{ key empty$
    { journal empty$
	{ "need key or journal for " cite$ * " to crossref " * crossref *
	  warning$
	  ""
	}
	{ "In {\em " journal * "\/}" * }
      if$
    }
    { "In " key * }
  if$
  " \cite{" * crossref * "}" *
}

FUNCTION {format.crossref.editor}
{ editor #1 "{vv~}{ll}" format.name$
  editor num.names$ duplicate$
  #2 >
    { pop$ " et~al." * }
    { #2 <
	'skip$
	{ editor #2 "{ff }{vv }{ll}{ jj}" format.name$ "others" =
	    { " and~al." * }
	    { " and " * editor #2 "{vv~}{ll}" format.name$ * }
	  if$
	}
      if$
    }
  if$
}

FUNCTION {format.book.crossref}
{ volume empty$
    { "empty volume in " cite$ * "'s crossref of " * crossref * warning$
      "In "
    }
    { "Volume" volume tie.or.space.connect
      " de " *
    }
  if$
  editor empty$
  editor field.or.null author field.or.null =
  or
    { key empty$
	{ series empty$
	    { "need editor, key, or series for " cite$ * " to crossref " *
	      crossref * warning$
	      "" *
	    }
	    { "{\em " * series * "\/}" * }
	  if$
	}
	{ key * }
      if$
    }
    { format.crossref.editor * }
  if$
  " \cite{" * crossref * "}" *
}

FUNCTION {format.inbook.crossref}
{ format.chapter.pages
  " de \cite{" * crossref * "}" *
}


FUNCTION {format.incoll.inproc.crossref}
{ "\emph{In :}~\cite{" crossref * "}" *
}

FUNCTION {format.address.publisher}
{ publisher empty$
    { "" }
    { address empty$
        { publisher }
        { address " : " publisher * *}
      if$
    }
  if$
}

FUNCTION {format.book.pages}
{ pages empty$
    { "" }
    { pages "~p." * }
  if$
 }

FUNCTION {format.isbn}
{ isbn empty$
	{ "" }
	{ "ISBN~" isbn * }
  if$
 }

FUNCTION {format.url}
{ url empty$
	{ "" }
	{ "Available via the URL~{\texttt{<}}\url{" url * "}{\texttt{>}}" * 
	  accessdate empty$
	    'skip$
	    { " (viewed on " * accessdate * ")" * }
	  if$	
	}
  if$
 }

FUNCTION {article}
{ output.bibitem
  format.authors "author" output.check
  new.block
  format.title "title" output.check
  new.block
  journal emphasize "journal" output.check
  new.sentence
  format.date "year" output.check
  format.vol.num.pages output
  new.block
  note output
  new.block
  format.url output  
  fin.entry
}

FUNCTION {book}
{ output.bibitem
  author empty$
    { editor empty$
		{ organization "u" change.case$ "author, editor and organization" output.check }
	    { format.editors output.nonnull }
	  if$
	}
    { format.authors output.nonnull }
  if$
  new.block
  format.btitle "title" output.check
  new.sentence
  format.edition output
  new.block
  format.address.publisher "publisher" output.check
  format.date "date" output.check
  new.block
  format.book.pages output
  new.block
  format.number.series output
  new.block
  note output
  new.block
  format.url output
  new.block
  format.isbn output
  fin.entry
}

FUNCTION {proceedings}
{ output.bibitem
  editor empty$
    { organization "u" change.case$ "editor and organization" output.check }
    { format.editors output.nonnull }
  if$
  new.block
  format.btitle "title" output.check
  new.block
  format.address.publisher "publisher" output.check
  format.date "year" output.check
  new.block
  format.book.pages output
  new.block
  format.number.series output
  new.sentence
  note output
  fin.entry
}

FUNCTION {inbook.has.own.title}
{ booktitle empty$ title empty$ or
  title field.or.null booktitle field.or.null = or
  not
}

FUNCTION {inbook.has.own.author}
{ bookauthor empty$ author empty$ or
  author field.or.null bookauthor field.or.null = or
  not
}


FUNCTION {format.inbook.booktitle}
{ inbook.has.own.title
    { "\emph{In :} " format.booktitle.volume * }
    { title empty$
        { "" }
        { "\emph{In :} " format.btitle * }
      if$
    }
  if$
}

FUNCTION {format.inbook.bookauthor}
{ inbook.has.own.author
    { bookauthor format.names }
    { "" }
  if$
}

FUNCTION {format.inbook.hostref}
{ inbook.has.own.title
    { "\emph{In :} " 
      inbook.has.own.author 
        { bookauthor format.names * ", " * }
        'skip$
      if$
      format.booktitle.volume * 
    }
    { title empty$
        { "" }
        { "\emph{In :} " 
          inbook.has.own.author 
	        { bookauthor format.names * ", " * }
	        'skip$
	      if$
          format.btitle *
        }
      if$
    }
  if$
}

FUNCTION {inbook}
{ output.bibitem
  author empty$
    { editor empty$
		{ organization "u" change.case$ "author, editor and organization" output.check }
	    { format.editors output.nonnull }
	  if$
   	}
    { format.authors output.nonnull }
  if$
  new.block 
  chapter empty$
  	{ inbook.has.own.title	
	    { title output.nonnull }
	    { format.pages "part identification" output.check }
	  if$
	}
	{ format.chapter 
	  inbook.has.own.title	
	    { " : " * title * }
	    'skip$
	  if$
	  output.nonnull
	}
  if$
  new.block
  crossref missing$
    { format.inbook.hostref "host title" output.check
      format.edition output
      format.address.publisher "publisher" output.check
      format.date "year" output.check
      format.number.series output 
      chapter empty$ inbook.has.own.title not and
	  	'skip$
		{ format.abbrev.pages output }
	  if$
    }
    { "\emph{In :} \cite{" crossref * "}" * output.nonnull
	  chapter empty$ inbook.has.own.title not and
	  	'skip$
		{ format.abbrev.pages output }
	  if$      
    }
  if$
  new.block
  note output
  fin.entry
}

FUNCTION {incollection}
{ output.bibitem
  format.authors "author" output.check
  new.block
  format.title "title" output.check
  new.block
  crossref missing$
    { format.in.ed.booktitle "booktitle" output.check
      format.edition output
      format.address.publisher "publisher" output.check
	  format.date "year" output.check
	  format.number.series output
      format.chapter.pages "l" change.case$ output     
    }
    { format.incoll.inproc.crossref output.nonnull
      format.chapter.pages "l" change.case$ output
    }
  if$
  new.block
  note output
  fin.entry
}

FUNCTION {inproceedings}
{ output.bibitem
  format.authors "author" output.check
  new.block
  format.title "title" output.check
  new.block
  crossref missing$
    { format.in.ed.booktitle "booktitle" output.check
      format.address.publisher "publisher" output.check
	  format.date "year" output.check
	  format.number.series output
	  format.abbrev.pages output
    }
    { format.incoll.inproc.crossref output.nonnull
      format.abbrev.pages output
    }
  if$
  new.block
  note output
  fin.entry
}

FUNCTION {conference} { inproceedings }

FUNCTION {booklet}
{ output.bibitem
  format.authors output
  new.block
  format.title "title" output.check
  howpublished address new.block.checkb
  howpublished output
  address output
  format.date output
  new.block
  note output
  fin.entry
}

FUNCTION {manual}
{ output.bibitem
  author empty$
    { organization empty$
	'skip$
	{ organization output.nonnull
	  address output
	}
      if$
    }
    { format.authors output.nonnull }
  if$
  new.block
  format.btitle "title" output.check
  new.sentence
  format.edition output
  author empty$
    { organization empty$
	{ address new.block.checka
	  address output
	}
	'skip$
      if$
    }
    { organization address new.block.checkb
      organization output
      address output
    }
  if$
  format.date output
  new.block
  note output
  fin.entry
}

FUNCTION {mastersthesis}
{ output.bibitem
  format.authors "author" output.check
  new.block
  format.title "title" output.check
  new.block
  "Master's thesis" format.thesis.type output.nonnull
  school "school" output.check
  address output
  format.date "year" output.check
  new.block
  format.book.pages output
  new.block
  note output
  fin.entry
}

FUNCTION {misc}
{ output.bibitem
  format.authors output
  title howpublished new.block.checkb
  format.title output
  howpublished new.block.checka
  howpublished output
  format.date output
  new.block
  note output
  new.block
  format.url output  
  fin.entry
  empty.misc.check
}

FUNCTION {phdthesis}
{ output.bibitem
  format.authors "author" output.check
  new.block
  format.btitle "title" output.check
  new.block
  "PhD Thesis" format.thesis.type output.nonnull
  school "school" output.check
  address output
  format.date "year" output.check
  new.block
  format.book.pages output
  new.block
  note output
  fin.entry
}


FUNCTION {techreport}
{ output.bibitem
  format.authors "author" output.check
  new.block
  format.title "title" output.check
  new.block
  format.tr.number output.nonnull
  institution "institution" output.check
  address output
  format.date "year" output.check
  new.block
  note output
  fin.entry
}

FUNCTION {unpublished}
{ output.bibitem
  format.authors "author" output.check
  new.block
  format.title "title" output.check
  new.block
  note "note" output.check
  format.date output
  fin.entry
}

FUNCTION {default.type} { misc }

MACRO {jan} {"January"}

MACRO {feb} {"February"}

MACRO {mar} {"March"}

MACRO {apr} {"April"}

MACRO {may} {"May"}

MACRO {jun} {"June"}

MACRO {jul} {"July"}

MACRO {aug} {"August"}

MACRO {sep} {"September"}

MACRO {oct} {"October"}

MACRO {nov} {"November"}

MACRO {dec} {"December"}

READ

FUNCTION {sortify}
{ purify$
  "l" change.case$
}

INTEGERS { len }

FUNCTION {chop.word}
{ 's :=
  'len :=
  s #1 len substring$ =
    { s len #1 + global.max$ substring$ }
    's
  if$
}

FUNCTION {sort.format.names}
{ 's :=
  #1 'nameptr :=
  ""
  s num.names$ 'numnames :=
  numnames 'namesleft :=
    { namesleft #0 > }
    { nameptr #1 >
	{ "   " * }
	'skip$
      if$
      s nameptr "{vv{ } }{ll{ }}{  ff{ }}{  jj{ }}" format.name$ 't :=
      nameptr numnames = t "others" = and
	{ "et al" * }
	{ t sortify * }
      if$
      nameptr #1 + 'nameptr :=
      namesleft #1 - 'namesleft :=
    }
  while$
}

FUNCTION {sort.format.title}
{ 't :=
  "A " #2
    "An " #3
      "The " #4 t chop.word
    chop.word
  chop.word
  sortify
  #1 global.max$ substring$
}

FUNCTION {author.sort}
{ author empty$
    { key empty$
	{ "to sort, need author or key in " cite$ * warning$
	  ""
	}
	{ key sortify }
      if$
    }
    { author sort.format.names }
  if$
}

FUNCTION {author.editor.sort}
{ author empty$
    { editor empty$
	{ key empty$
	    { "to sort, need author, editor, or key in " cite$ * warning$
	      ""
	    }
	    { key sortify }
	  if$
	}
	{ editor sort.format.names }
      if$
    }
    { author sort.format.names }
  if$
}

FUNCTION {author.editor.organization.sort}
{ author empty$
    { editor empty$
        { organization empty$
	        { key empty$
	            { "to sort, need author, editor, organization or key in " cite$ * warning$
	              ""
	            }
	            { key sortify }
	          if$
	         }
			 { "The " #4 organization chop.word sortify }
		  if$
		}
		{ editor sort.format.names }
      if$
    }
    { author sort.format.names }
  if$
}

FUNCTION {author.organization.sort}
{ author empty$
    { organization empty$
	{ key empty$
	    { "to sort, need author, organization, or key in " cite$ * warning$
	      ""
	    }
	    { key sortify }
	  if$
	}
	{ "The " #4 organization chop.word sortify }
      if$
    }
    { author sort.format.names }
  if$
}

FUNCTION {editor.organization.sort}
{ editor empty$
    { organization empty$
	{ key empty$
	    { "to sort, need editor, organization, or key in " cite$ * warning$
	      ""
	    }
	    { key sortify }
	  if$
	}
	{ "The " #4 organization chop.word sortify }
      if$
    }
    { editor sort.format.names }
  if$
}

FUNCTION {presort}
{ type$ "book" =
    'author.editor.organization.sort
	{ type$ "inbook" =
	    'author.editor.sort
		{ type$ "proceedings" =
			'editor.organization.sort
			{ type$ "manual" =
			    'author.organization.sort
			    'author.sort
			  if$
			}
		  if$
		}
	  if$
	}
  if$
  "    " *
  year field.or.null sortify *
  "    " *
  title field.or.null sort.format.title *
  #1 entry.max$ substring$
  'sort.key$ :=
}

ITERATE {presort}

SORT

STRINGS { longest.label }

INTEGERS { number.label longest.label.width }

FUNCTION {initialize.longest.label}
{ "" 'longest.label :=
  #1 'number.label :=
  #0 'longest.label.width :=
}

FUNCTION {longest.label.pass}
{ number.label int.to.str$ 'label :=
  number.label #1 + 'number.label :=
  label width$ longest.label.width >
    { label 'longest.label :=
      label width$ 'longest.label.width :=
    }
    'skip$
  if$
}

EXECUTE {initialize.longest.label}

ITERATE {longest.label.pass}

FUNCTION {begin.bib}
{ preamble$ empty$
    'skip$
    { preamble$ write$ newline$ }
  if$
  "\begin{thebibliography}{"  longest.label  * "}" * write$ newline$
}

EXECUTE {begin.bib}

EXECUTE {init.state.consts}

ITERATE {call.type$}

FUNCTION {end.bib}
{ newline$
  "\end{thebibliography}" write$ newline$
}

EXECUTE {end.bib}